!---------------------------------------------------------------------------
!	ExpertGrammar.h, by Emily Short (emshort@mindspring.com) 
!	Traducida y adaptada a InformATE por Mapache (mapache2004@gmail.com) (11/08/2005)
!
!	
!	Esta librería pretende ser una ampliación a los verbos manejados por la librería 
!	estándar. Respecto a los verbos traducidos, no están todos debido a que algunos
!	ya se encontraban en InformATE
!
!	Se ha incluido el uso de la constante conUsar. (No me gusta el verbo "usar" :])
!
!	Version 0.1 de la traducción al castellano basada en
!	
!	Version 0.6 -- still in progress.  Let me know if you have 
!		more suggestions.
!
!	5/21/03
!
!	Thanks to Daniel Lackey for his corrections.
!
!	DERECHOS:
!	La librería puede ser tratada como dominio público. Puede ser
!	incluida con o sin dar crédito al autor original. Puede ser modificada
!	a voluntad del usuario. Puede ser libremente redistribuida. Partes pueden ser
!	extraidas.
!
!	CONTENIDO:
!	Los verbos se autoexplican... tal vez quieras ajustar los mensajes por defecto
!	a tu juego, y capturar las nuevas acciones en los objetos necesarios.
!
!	INSTALACIÓN: 
!
!	Incluir la linea
!	Include "GramaticaExperta";
!	despues de la linea
!	Include "Gramatica";	
!
!	Si se desea que se reconozca el verbo usar, definir la constante conUsar de este modo
!	Constant conUsar;
!---------------------------------------------------------------------------


Verb		'marcha'				= 'ir';

Verb		'talla' 'esculpe'			= 'corta';

Verb		'roba' 'agarra'				= 'coge';		

Verb		'emplaza' 'deposita'			= 'deja';

Extend 	'grita'	last
				* 			-> Gritar;
Verb		'berrea'	'aulla'			= 'grita';

Verb		'machaca'				= 'ataca';

Verb		'monta'					= 'entra';

Verb		'abandona'				= 'deja';

Verb		'incinera' 'tuesta'			= 'quema';
VerboIrregular	"tostar" with imperativo 'tuesta';

Verb		'silba' 'tararea' 'tatarea'	= 'canta';
Extend	'canta'	
				* topic 		-> Cantar;

!Constant conUsar; Por defecto no queremos que usar sea comodin de todo

#ifdef conUsar; ! Modo "avanzado" del verbo usar
Verb 	'usa' 'utiliza' 'emplea'
				*  prenda		-> Vestir
				*  comestible		-> Comer
				*  entrable		-> Entrar
				*  puerta		-> Entrar
				*  conmutable 		-> Encender
				*  abrible		-> Abrir
				* noun			-> Usar
				* noun 	'en'/'con'  cerrojo	-> ProbarLlave
				* noun	 'a'/'para' topic	-> NadaDeUsar;
#ifnot;
Verb 	'usa' 'utiliza' 'emplea'
			   	* 			-> Usar
				* topic			-> Usar
			    	* noun			-> NadaDeUsar;
#endif;

Verb		'muerde'		
				* comestible		-> Comer
				* noun			-> Atacar;

Verb		'desciende'	
				*			-> Descender
				* noun			-> Entrar
				* 'por' noun		-> Entrar;
VerboIrregular "descender" with imperativo	'desciende';				

Verb		'asciende'	
				*			-> Ascender
				* noun			-> Entrar
				* 'por' noun		-> Entrar;
VerboIrregular "ascender" with imperativo	'asciende';				
					
Verb		'llama'		
				* 'a' noun		-> LlamarA;
					 
Verb		'baila'		
				*			-> Bailar;

Verb		'desata' 'libera'
				* noun			-> Desatar;

Verb		'activa' 	
				* noun			-> Encender;

Extend 	'pon' first	
				* noun 'en' 'marcha'	-> Encender;
					
Verb 	'para' 'desactiva'
				* noun			-> Apagar;

Verb 	'suicida'	
				* '-me'/'-te'		-> Finalizar;

Extend	'comete' first 
				* 'suicidio'		-> Finalizar;

Extend 	'mata' 	first 
				* '-me'/'-te'		-> Finalizar;

Extend	'mira'	
				* 'alrededor'		-> Mirar;

Extend 	'cava'  first
				*			-> CavarSuelo
				* 'con'	held 		-> CavarSuelo;

Extend 	'excava' first
				*			-> CavarSuelo
				* 'con'	held 		-> CavarSuelo;

Extend 	'sopla' 
				* 'sobre'/'dentro'/'a'	noun 	-> SoplarEn
				* 'a' 'traves' 'de' 	noun 	-> SoplarEn;

Extend 	'reza'	
				* 'a'/'por' topic	 -> Rezar;


[CavarSueloSub;
	if(uno) <<Excavar obj_abajo uno>>;
	else <<Excavar obj_abajo>>;
];

[ AscenderSub;
	<<Ir obj_arriba>>;
];
[ DescenderSub;
	<<Ir obj_abajo>>;
];


[ UsarSub;
	"No está totalmente claro qué acción pretendes realizar.";
];

#ifdef conUsar;
[ProbarLlaveSub;
	if(otro has cerrojo)<<quitarcerrojo otro>>;
	<<echarcerrojo otro>>;
];
#endif;

[ NadaDeUsarSub;
    "Tratas de encontrar un uso para ", (el) uno, " pero tu mente no 
	acierta con la acción concreta.";
];

[ DesatarSub;
	"No está totalmente claro qué pretendes.";	
];

[SoplarEnSub;
	"Tu soplido no produce ningún efecto";
];

[ BailarSub;
	"Tu nunca has sido un buen bailarín.";
];

[LlamarASub;
	if (uno has puerta) "Nadie contesta.";
	"No pasa nada.";
];
[GritarSub;
	"~¡AARRGHH!~";
];